ASTDR source

Revision as of 08:37, 12 November 2015

source: http://pastebin.com/P3uun3x4

# ASTDR DeRainbow function v1.51
 
  function ASTDR(clip input, int "strength", int "tempsoftth", int "tempsoftrad", int "tempsoftsc", float "blstr", int "tht", int "FluxStv", int "dcn", bool "edgem")
  {
  strn          = Default(strength, 5)
  blstr         = Default(blstr, 0.5)
  tht           = Default(tht, 255)
  tschrth       = Default(tempsoftth, 30)
  tschrrad      = Default(tempsoftrad, 3)
  tschrsc       = Default(tempsoftsc, 3)
  FluxStv       = Default(FluxStv, 75)
  dcn           = Default(dcn, 15)
  edgem         = default(edgem, false)

  momask    = input.tweak(sat=1.1).mt_motion(thc2=1,thc1=1,thy2=1,thy1=1,y=3,v=3,u=3,tht=tht)
  momaskinv = momask.mt_expand(u=3, v=3).mt_inflate(u=3, v=3).Invert().Levels(0,2,255,0,255)
 
  filtered_uv = input.DeCross(ThresholdY=15, Noise=dcn, Margin=1).FluxSmoothST(FluxStv,FluxStv).Mergeluma(input).awarpsharp2(depth=4,chroma=6).hqdn3d(ls=0,lt=0,cs=strn*3/5,ct=strn)
              \ .temporalsoften(tschrrad,0,tschrth,tschrsc,2).blur(blstr).Mergeluma(input).aWarpSharp2(depth=4,chroma=6).fft3dfilter(sigma=1,sigma3=4,plane=3,degrid=1)
 
  filtered = mt_merge(filtered_uv, input, momaskinv,y=2,u=3,v=3,luma=true)
  
  mt_merge(input, filtered, momask.mt_expand(mode="both", y=3,u=3,v=3).mt_inflate(y=3,u=3,v=3),y=2,u=3,v=3)
  edgem ? mt_merge(input, last, input.mt_edge("sobel", 4, 4, 4, 4, u=3, v=3).mt_expand(u=3, v=3).mt_inflate(u=3, v=3),y=2,u=3,v=3,luma=true) : last
  }

# ASTDRmc DeRainbow function v1.0

  function ASTDRmc(clip prerb, int "strength", int "tempsoftth", int "tempsoftrad", int "tempsoftsc", float "blstr", int "tht", int "FluxStv", int "dcn", bool "edgem")
  {
derbmask = (VersionNumber() < 2.60) ? prerb.tedgemask(threshY=2).mt_inflate() : prerb.TEMmod(threshY=2).mt_inflate()
derbsuper = prerb.MSuper()
derbbackward_vectors = MAnalyse(derbsuper, truemotion = true, isb = true, chroma=false)
derbforward_vectors = MAnalyse(derbsuper, truemotion = true, isb = false, chroma=false)
derbforward_compensation = prerb.MCompensate(derbsuper, derbforward_vectors)
derbbackward_compensation = prerb.MCompensate(derbsuper, derbbackward_vectors)
mcclip = interleave(derbforward_compensation,prerb,derbbackward_compensation)
ASTDRclip = mcclip.ASTDR(strength=strength,tempsoftth=tempsoftth,tempsoftrad=tempsoftrad,tempsoftsc=tempsoftsc,blstr=blstr,tht=tht,FluxStv=FluxStv,dcn=dcn,edgem=edgem).selectevery(3,1)
mt_merge(prerb,ASTDRclip, derbmask,luma=true,y=2,u=3,v=3)
  }