GetChannel

From Avisynth wiki
Revision as of 04:09, 15 February 2016 by Raffriff42 (Talk | contribs)
Jump to: navigation, search

GetChannel(clip clip, int ch1 [, int ch2, ...] )
GetChannels(clip clip, int ch1 [, int ch2, ...] )
GetLeftChannel(clip clip)
GetRightChannel(clip clip)

  • GetChannel returns one or more channels of a multichannel signal.
  • GetLeftChannel returns the left channel from a stereo signal, and GetRightChannel returns the right.
  • GetChannels is an alias for GetChannel and can be used interchangeably.


The ordering of the channels is determined by the ordering of the input file, because AviSynth doesn't assume any ordering (see Remarks).

In case of WAV files, the ordering should be as follows:

  WAV, 2 channels (stereo) 
1 left
2 right
  WAV, 5.1 channels 
2 front right
3 front center
4 LFE (Low Frequency Enhancement; Subwoofer)
5 rear left
6 rear right


Remarks

Every file format has a different internal channel ordering. The following table gives this internal ordering for some formats (useful for plugin writers), but it is the decoder's task to return the expected channel order. If you use decoders like NicAudio/BassAudio or ffdshow/AC3Filter you don't need to worry about this.

Format Channel 1 Channel 2 Channel 3 Channel 4 Channel 5 Channel 6
5.1 WAV front left front right front center  LFE rear left rear right
5.1 AC3 front left front center  front right rear left rear right  LFE
5.1 DTS ¹ front center  front left front right rear left rear right LFE
5.1 AAC ² front center  front left front right rear left rear right LFE
5.1 AIFF front left rear left front center  front right  rear right LFE
5.1 FLAC front left front right front center  LFE rear left rear right 
5.1 WMA   front left front right front center  LFE rear left rear right 

¹ 5.1 DTS: the LFE is on a separate stream (much like on multichannel MPEG2).
² There is no free version of the AAC specification available online.


Examples

  • Remove right channel information, and return as mono clip with only left channel:
video = AviSource("c:\filename.avi")
stereo = WavSource("c:\afx-ab3_t4.wav")
mono = GetLeftChannel(stereo)
return AudioDub(video, mono)
  • Do the same, alternate syntax:
video = AviSource("c:\filename.avi")
stereo = WavSource("c:\afx-ab3_t4.wav")
mono = GetChannel(stereo, 1)
return AudioDub(video, mono)
  • You could also obtain the channels from the AVI file itself:
video = AviSource("c:\filename.avi")
return GetChannel(video, 1)
  • Convert AVI with 5.1 audio to a stereo signal

(But see below for channel ordering, and here for more complex downmix functions.)

video = AviSource("c:\divx_51.avi")
stereo = GetChannel(video, 1, 2)
return AudioDub(video, stereo)
  • Convert AVI with "uncompressed 5.1 wav" audio to a stereo signal:
video = AviSource("c:\divx_wav.avi")
audio = WavSource("c:\divx_wav.avi")
stereo = GetChannel(audio, 1, 2)
return AudioDub(video, stereo)
  • Mix 5.1 AC3 to stereo - see discussion here.

Note returned audio is Float type. Normalize is recommended before converting to 16-bit to avoid possible overload.

function DownMix(clip a, 
\     float "centergain", float "surroundgain")
{
   a.ConvertAudioToFloat()

   ## channel layouts: (AC3, the most common)
   fl = GetChannel(1)
   fr = GetChannel(2)
   fc = GetChannel(3)
   lf = GetChannel(4)
   sl = GetChannel(5)
   sr = GetChannel(6)

   ## add center
   gc = Default(centergain, 1.0) * 0.7071
   fl = MixAudio(fl, fc, 1.0, gc)
   fr = MixAudio(fr, fc, 1.0, gc)

   ## add surround
   gs = Default(surroundgain, 1.0) * 0.7071
   fl = MixAudio(fl, sl, 1.0, gs)
   fr = MixAudio(fr, sr, 1.0, gs)

   return AudioDub(a, MergeChannels(fl, fr))
}
Personal tools